Android.bat file is missing in sdk\tools folder also i do not having AVD & SDK manager in tools so i can replace them

Question

i have also copied android.bat from my backup SDK but it is still not working. thanks in advance.

Solution 1

Probably all the contents of the sdk/tools folder are missing as well?

Best method to solve this issue is to go to the sdk/temp folder. There you will find a zip file with a name like "tools_r24.0.1-windows" (version number will be different)

Copy it to someplace and extract it. Inside the extracted folder you'll have a folder named 'tools'

Copy that folder to sdk/ and replace the current tools folder in sdk/

And voila! SDK and AVD will work again and all your virtual devices will be restored!

Solution 2

The Best Solution i have is download the SDK Tools Only From: http://developer.android.com/sdk/index.html

->Other Download Options->SDK Tools Only->android-sdk_r24.*.*-windows.zip
Update: Web content updated now you need to go to the section below

"Get just the command line tools" (Download tools according to your operating system)

.
and extract it into your sdk location where the tools required.

Solution 3

I actually don't understand, why you don't download it from somewhere else, but here is the Android.bat:

@echo off
rem Copyright (C) 2007 The Android Open Source Project
rem
rem Licensed under the Apache License, Version 2.0 (the "License");
rem you may not use this file except in compliance with the License.
rem You may obtain a copy of the License at
rem
rem      http://www.apache.org/licenses/LICENSE-2.0
rem
rem Unless required by applicable law or agreed to in writing, software
rem distributed under the License is distributed on an "AS IS" BASIS,
rem WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
rem See the License for the specific language governing permissions and
rem limitations under the License.

rem Useful links:
rem Command-line reference:
rem   http://technet.microsoft.com/en-us/library/bb490890.aspx

rem don't modify the caller's environment
setlocal

rem Set up prog to be the path of this script, including following symlinks,
rem and set up progdir to be the fully-qualified pathname of its directory.
set prog=%~f0

rem Grab current directory before we change it
set work_dir=%cd%

rem Change current directory and drive to where the script is, to avoid
rem issues with directories containing whitespaces.
cd /d %~dp0


rem Check we have a valid Java.exe in the path.
set java_exe=
call lib\find_java.bat
if not defined java_exe goto :EOF

set jar_path=lib\sdkmanager.jar;lib\swtmenubar.jar

rem Set SWT.Jar path based on current architecture (x86 or x86_64)
for /f "delims=" %%a in ('"%java_exe%" -jar lib\archquery.jar') do set swt_path=lib\%%a

:MkTempCopy
    rem Copy android.bat and its required libs to a temp dir.
    rem This avoids locking the tool dir in case the user is trying to update it.

    set tmp_dir=%TEMP%\temp-android-tool
    xcopy %swt_path% %tmp_dir%\%swt_path% /I /E /C /G /R /Y /Q > nul
    copy /B /D /Y lib\common.jar         %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\commons-codec*     %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\commons-compress*  %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\commons-logging*   %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\dvlib.jar          %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\guava*             %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\httpclient*        %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\httpcore*          %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\httpmime*          %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\layoutlib-api.jar  %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\org-eclipse-*      %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\sdk*               %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\swtmenubar.jar     %tmp_dir%\lib\        > nul

    rem jar_path and swt_path are relative to PWD so we don't need to adjust them, just change dirs.
    set tools_dir=%cd%
    cd /d %tmp_dir%

:EndTempCopy

rem The global ANDROID_SWT always override the SWT.Jar path
if defined ANDROID_SWT set swt_path=%ANDROID_SWT%

if exist "%swt_path%" goto SetPath
    echo ERROR: SWT folder '%swt_path%' does not exist.
    echo Please set ANDROID_SWT to point to the folder containing swt.jar for your platform.
    goto :EOF

:SetPath
rem Finally exec the java program and end here.
REM set REMOTE_DEBUG=-Xdebug -Xrunjdwp:transport=dt_socket,server=y,suspend=y,address=8000
call "%java_exe% %REMOTE_DEBUG%" "-Dcom.android.sdkmanager.toolsdir=%tools_dir%" "-Dcom.android.sdkmanager.workdir=%work_dir%" -classpath "%jar_path%;%swt_path%\swt.jar" com.android.sdkmanager.Main %*

rem EOF

Comments

[Mark McClelland]

My tools download failed part way through. I ran the update again and the download succeeded, but then the update got hung up because the tools directory was in use by another application. When I exited everything and investigated, it turned out my tools directory was empty, except the support directory. Extracting the tools directory from my temp folder did the trick. Thanks!

[Marcin D]

this guy s an angel sent from heaven

[Dheeraj Bhaskar]

didn't use this, but would've been my next option. Thanks

[Hardik Parmar]

@Sndn its very very use full. Thank you so much.

[atp03]

This worked! Installing Android SDK has been nothing but frustration. The size is ridiculously huge and trying to install it on a secondary drive (as the installer suggests that you can) is useless as there's a bunch of hidden folders that still makes it to the boot drive and taking up several GBs.

[Ray Goudie]

This worked for me with Visual Studio 2017 Community Edition. The tools directory was missing.

[melwil]

This answer is wildly underappreciated. Just had this problem myself. I was attempting upgrading 25.2.5 -> 26.1.1. Tools folder was there, but a lot of other parts were missing. Downloaded the tools only and extracted it to C:\Program Files (x86)\Android\android-sdk\tools, then restarted VS and they were back.

[Ahmad]

where is other download option in visual studio ?

[Moosa Baloch]

@Ahmad : Download tool from this link dl.google.com/android/repository/sdk-tools-windows-3859397.z‌​ip and extract it into your SDK location. that's it.

[cd491415]

My temp directory does not contain any tools_xxx.zip files

[jrypkahauer]

If you have the Android SDK already installed and the Android SDK Manager is grayed out... In VS 2017 you can do Tools > Options > Tools For Apache Cordova > Environment Variable Overrides, then point it at your Android SDK folder and hit OK. We literally did this 5 minutes ago to fix the problem.