element() vs. node() in XQuery

Question

Can someone tell me the exact difference between node() and element() types in XQuery? The documentation states that element() is an element node, while node() is any node, so if I understand it correctly element() is a subset of node().

The thing is I have an XQuery function like this:

declare function local:myFunction($arg1 as element()) as element() {
    let $value := data($arg1/subelement)
   etc...
};

Now I want to call the function with a parameter which is obtained by another function, say functionX (which I have no control over):

let $parameter := someNamespace:functionX()
return local:myFunction($parameter)

The problem is, functionX returns an node() so it will not let me pass the $parameter directly. I tried changing the type of my function to take a node() instead of an element(), but then I can’t seem to read any data from it. $value is just empty.

Is there some way of either converting the node to an element or should am I just missing something?

EDIT: As far as I can tell the problem is in the part where I try to get the subelement using $arg1/subelement. Apparently you can do this if $arg1 is an element() but not if it is a node().

UPDATE: I have tested the example provided by Dimitre below, and it indeed works fine, both with Saxon and with eXist DB (which is what I am using as the XQuery engine). The problem actually occurs with the request:get-data() function from eXist DB. This function gets data provided by the POST request when using eXist through REST, parses it as XML and returns it as a node(). But for some reason when I pass the data to another function XQuery doesn’t acknowledge it as being a valid element(), even though it is. If I extract it manually (i.e. copy the output and paste it to my source code), assign it to a variable and pass it to my function all goes well. But if I pass it directly it gives me a runtime error (and indeed fails the instance of test).

I need to be able to either make it ignore this type-check or “typecast” the data to an element().

Solution 1

data() returning empty for an element just because the argument type is node() sounds like a bug to me. What XQuery processor are you using?

It sounds like you need to placate static type checking, which you can do using a treat as expression. I don't believe a dynamic test using instance of will suffice.

Try this:

let $parameter := someNamespace:functionX() treat as element()
return local:myFunction($parameter)

Quoting from the 4th edition of Michael Kay's magnum opus, "The treat as operator is essentially telling the system that you know what the runtime type is going to be, and you want any checking to be deferred until runtime, because you're confident that your code is correct." (p. 679)

UPDATE: I think the above is actually wrong, since treat as is just an assertion. It doesn't change the type annotation node(), which means it's also a wrong assertion and doesn't help you. Hmmm... What I really want is cast as, but that only works for atomic types. I guess I'm stumped. Maybe you should change XQuery engines. :-) I'll report back if I think of something else. Also, I'm curious to find out if Dimitre's solution works for you.

UPDATE #2: I had backpedaled here earlier. Can I backpedal again? ;-) Now my theory is that treat as will work based on the fact that node() is interpreted as a union of the various specific node type annotations, and not as a run-time type annotation itself (see the "Note" in the "Item types" section of the XQuery formal semantics.) At run time, the type annotation will be element(). Use treat as to guarantee to the type checker that this will be true. Now I wait on bated breath: does it work for you?

EXPLANATORY ADDENDUM: Assuming this works, here's why. node() is a union type. Actual items at run time are never annotated with node(). "An item type is either an atomic type, an element type, an attribute type, a document node type, a text node type, a comment node type, or a processing instruction type."1 Notice that node() is not in that list. Thus, your XQuery engine isn't complaining that an item has type node(); rather it's complaining that it doesn't know what the type is going to be (node() means it could end up being attribute(), element(), text(), comment(), processing-instruction(), or document-node()). Why does it have to know? Because you're telling it elsewhere that it's an element (in your function's signature). It's not enough to narrow it down to one of the above six possibilities. Static type checking means that you have to guarantee—at compile time—that the types will match up (element with element, in this case). treat as is used to narrow down the static type from a general type (node()) to a more specific type (element()). It doesn't change the dynamic type. cast as, on the other hand, is used to convert an item from one type to another, changing both the static and dynamic types (e.g., xs:string to xs:boolean). It makes sense that cast as can only be used with atomic values (and not nodes), because what would it mean to convert an attribute to an element (etc.)? And there's no such thing as converting a node() item to an element() item, because there's no such thing as a node() item. node() only exists as a static union type. Moral of the story? Avoid XQuery processors that use static type checking. (Sorry for the snarky conclusion; I feel I've earned the right. :-) )

NEW ANSWER BASED ON UPDATED INFORMATION: It sounds like static type checking is a red herring (a big fat one). I believe you are in fact not dealing with an element but a document node, which is the invisible root node that contains the top-level element (document element) in the XPath data model representation of a well-formed XML document.

The tree is thus modeled like this:

      [document-node]
             |
        <docElement>
             |
        <subelement>

and not like this:

        <docElement>
             |
        <subelement>

I had assumed you were passing the <docElement> node. But if I'm right, you were actually passing the document node (its parent). Since the document node is invisible, its serialization (what you copied and pasted) is indistinguishable from an element node, and the distinction was lost when you pasted what is now interpreted as a bare element constructor in your XQuery. (To construct a document node in XQuery, you have to wrap the element constructor with document{ ... }.)

The instance of test fails because the node is not an element but a document-node. (It's not a node() per se, because there's no such thing; see explanation above.)

Also, this would explain why data() returns empty when you tried to get the <subelement> child of the document node (after relaxing the function argument type to node()). The first tree representation above shows that <subelement> is not a child of the document node; thus it returns the empty sequence.

Now for the solution. Before passing the (document node) parameter, get its element child (the document element), by appending /* (or /element() which is equivalent) like this:

let $parameter := someNamespace:functionX()/*
return local:myFunction($parameter)

Alternatively, let your function take a document node and update the argument you pass to data():

declare function local:myFunction($arg1 as document-node()) as element() {
    let $value := data($arg1/*/subelement)
   etc...
};

Finally, it looks like the description of eXist's request:get-data() function is perfectly consistent with this explanation. It says: "If its not a binary document, we attempt to parse it as XML and return a document-node()." (emphasis added)

Thanks for the adventure. This turned out to be a common XPath gotcha (awareness of document nodes), but I learned a few things from our detour into static type checking.

Solution 2

This works perfectly using Saxon 9.3:

declare namespace my = "my:my";
declare namespace their = "their:their";

declare function my:fun($arg1 as element()) as element() 
{
            $arg1/a
};

declare function their:fun2($arg1 as node()) as node() 
{
            $arg1
};

my:fun(their:fun2(/*) )

when the code above is applied on the following XML document:

<t>
  <a/>
</t>

the correct result is produced with no error messages:

<a/>

Update:

The following should work even with the most punctuential static type-checking XQuery implementation:

declare namespace my = "my:my";
declare namespace their = "their:their";

declare function my:fun($arg1 as element()) as element() 
{
            $arg1/a
};

declare function their:fun2($arg1 as node()) as node() 
{
            $arg1
};

 let $vRes :=  their:fun2(/*) 
  (: this prevents our code from runtime crash :)
  return if($vRes instance of  element())
     then
       (: and this assures the static type-checker 
          that the type is element() :)
       my:fun(their:fun2(/*) treat as element())
     else()

Solution 3

node() is an element, attribute, processing instruction, text node, etc.

But data() converts the result to a string, which isn't any of those; it's a primitive type.

You might want to try item(), which should match either.

See 2.5.4.2 Matching an ItemType and an Item in the W3C XQuery spec.

Although it's not shown in your example code, I assume you are actually returning a value (like the $value you are working with) from the local:myFunction.

Comments

[pajevic]

Hi lavinio. Thank you for the reply. However, I think there might be a misunderstanding. The problem is not in the return type of my function but in the type of the argument $arg1. For me to be able to pass the node returned by functionX, the type of $arg1 must be node(). But then I cannot read its data, which I am able to read just fine if the type is element().

[Evan Lenz]

Quick correction: data() returns a sequence of zero or more atomic values, not necessarily a string. If there's no schema, then the result is like a string but annotated as xs:untypedAtomic.

[Dimitre Novatchev]

Evan, Why do you doubt "if Dimitre's solution works" ? Just run it with Saxon, as I do always before posting code.

[Evan Lenz]

I meant if it works using the OP's XQuery engine, which appears to be using static type checking. If that's the case, then I don't think instance of will prevent the error message they're seeing.

[Dimitre Novatchev]

Evan, the OP says in his question that with his his code "you can do this if $arg1 is an element()" . This statement means that he gets only a runtime error -- in the cases when $arg1 isn't an element.

[Evan Lenz]

My interpretation was that he was getting an error despite passing in an element, i.e. an error that occurs unless $arg1 is known statically to be an element. I guess we'll both have to wait and see. :-)

[pajevic]

Thank you for the reply Dimitre. I have tested your code and it indeed does work. I suspected that the issue might be with the fact that I am using eXist DB as the xquery engine. However your example worked with eXist as well.

[pajevic]

Hi guys. Just to clarify the issue, the value I am passing to $arg1 does contain XML which by any definition should be a valid element().I suspect that it has something to do with how the request:get-data() function (se the update above) passes the XML, even though it should just be an node(). So in this case instance of does not solve the problem since it too becomes a victim of the “false” type-check. I am hoping that treat as will be the medicine I need, but I cannot test it until I come home later today.

[Dimitre Novatchev]

@NobleK: You are welcome. I have asked myself the theoretical question if a static type-checking processor is useful, but never have had the experience of using one. Now, seeing this practical example, I am starting to believe that all the hassle may indeed be worth it, because without the static error there could be cases of an XQuery app that seems to operate "normally" for some time and then suddenly starts producing runtime errors. If the application is of important nature (such as e-commerce), we, naturally don't want any unpredictable runtime errors.

[pajevic]

Wow, Evan, thank you for a really great job, sincerely. I believe that this is the most elaborate answer I have ever got on SO, which not only solved my problem but really made it clear to me what was causing it in the first place. And yes, you were right on the money – the /* did the job. I had actually read the documentation for request:get-data() but I missed the dash between “document” and “node” and read the return type to be a node() which then caused all the confusion for me :)