finding user's documents folder in .bat script

Question

What is the best way to find a user's Documents folder on XP and Vista from a batch script? Is it safe to assume that it's %USERPROFILE%\Documents?

Solution 1

so my final version looks like this:

FOR /F "tokens=3 delims= " %%G IN ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal"') DO (SET docsdir=%%G)

where the character between delims= and the following " is a single tab. Make sure your editor emits a tab and not spaces.

EDIT: On Windows 7 (and maybe all windows) you shouldn't specify delims= at all as it defaults to which is the whitespace used inbetween the tokens and not just a tab.

Solution 2

A complete reference of environment variables can be found here, on the microsoft site, it can also be found in a registry key.

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders
String value: Personal

In the event the My Documents folder is not in the standard location, pulling the information out the registry key is probably the most reliable way.

Solution 3

The best way to determine the location of My Documents is from the Windows Registry.

Several other answers and comments on this page have made reference to using "reg query". Below is the correct implementation that takes into account spaces in the path, as well as different versions of Windows:

for /f "tokens=1,2*" %%A in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal" 2^>nul') do (
   set RNAME=%%A
   set RTYPE=%%B
   set RDATA=%%C
)

Here is the one-liner for script writers:

for /f "tokens=1,2*" %%A in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal" 2^>nul') do set MY_DOCS_ROOT=%%C

This does not take into account localization or internationalization. This has not been tested on non-English versions of Windows. Comments on that topic are welcome.

This does work for Windows XP, Windows Vista, Windows 7, and Windows 8.

---

Note: Using the asterisk in the tokens= option is important for Windows XP, which usually contains spaces in the path for My Documents.

Note: If using implicit variables like %%B and %%C seems a little strange, you may have a look at this article:

http://ss64.com/nt/for_f.html

tokens=3* will process the third token and the 4th + all subsequent items, this can also be written as tokens=3,*

Each token specified will cause a corresponding parameter letter to be allocated. The letters used for tokens are case sensitive.

If the last character in the tokens= string is an asterisk, then additional parameters are allocated for all the remaining text on the line.

The first variable is declared in the FOR statement and subsequent variables will be implicitly declared via the tokens= option.

The linked article gives the exact ordering of the variables that will be declared implicitly, but it is essentially alphabetic.

(With three tokens, by declaring %%A in the FOR statement, %%B and %%C will be declared implicitly. In the same way, by declaring %%X in the FOR statement, %%Y and %%Z will be declared implicitly.)

Solution 4

It's only "My Documents" etc on english windows. If you're using another language the pathname is "translated" (except on Vista)

View more solutions

Comments

[JFV]

@squillman: I need to work on my typing speed! You smoked me on this answer! lol

[squillman]

Proof that time spent in chat rooms during college was worth it... :)

[David Kerr]

Thanks! Here's the registry query command for this value: reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\She‌​ll Folders" /v "Personal"

[voretaq7]

This looks like you want it to be a script? Please read our markdown editing/formatting guide and fix up your formatting. You may also want to add some description of what your script does and when/why you should/shouldn't use it.

[Andrew Arnott]

Removing the delims= works for me on Windows 8

[drescherjm]

This did not work for me because the Documents folder is redirected in my profile. The registry way works in that case.