How do I add a linker or compile flag in a CMake file?

Question

I am using the arm-linux-androideabi-g++ compiler. When I try to compile a simple "Hello, World!" program it compiles fine. When I test it by adding a simple exception handling in that code it works too (after adding -fexceptions .. I guess it is disabled by default).

This is for an Android device, and I only want to use CMake, not ndk-build.

For example - first.cpp

#include <iostream>
using namespace std;
int main()
{
   try
   {
   }
   catch (...)
   {
   }
   return 0;
}

./arm-linux-androideadi-g++ -o first-test first.cpp -fexceptions

It works with no problem...

The problem ... I am trying to compile the file with a CMake file.

I want to add the -fexceptions as a flag. I tried with

set (CMAKE_EXE_LINKER_FLAGS -fexceptions ) or set (CMAKE_EXE_LINKER_FLAGS "fexceptions" )

and

set ( CMAKE_C_FLAGS "fexceptions")

It still displays an error.

Solution 1

Note: Given CMake evolution since this was answer was written in 2012, most of the suggestions here are now outdated/deprecated and have better alternatives.

---

Suppose you want to add those flags (better to declare them in a constant):

SET(GCC_COVERAGE_COMPILE_FLAGS "-fprofile-arcs -ftest-coverage")
SET(GCC_COVERAGE_LINK_FLAGS    "-lgcov")

There are several ways to add them:

1. The easiest one (not clean, but easy and convenient, and works only for compile flags, C & C++ at once):

    add_definitions(${GCC_COVERAGE_COMPILE_FLAGS})
   

2. Appending to corresponding CMake variables:

    SET(CMAKE_CXX_FLAGS  "${CMAKE_CXX_FLAGS} ${GCC_COVERAGE_COMPILE_FLAGS}")
    SET(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS} ${GCC_COVERAGE_LINK_FLAGS}")
   

3. Using target properties, cf. doc CMake compile flag target property and need to know the target name.

    get_target_property(TEMP ${THE_TARGET} COMPILE_FLAGS)
    if(TEMP STREQUAL "TEMP-NOTFOUND")
      SET(TEMP "") # Set to empty string
    else()
      SET(TEMP "${TEMP} ") # A space to cleanly separate from existing content
    endif()
    # Append our values
    SET(TEMP "${TEMP}${GCC_COVERAGE_COMPILE_FLAGS}" )
    set_target_properties(${THE_TARGET} PROPERTIES COMPILE_FLAGS ${TEMP} )
   

Right now I use method 2.

Solution 2

In newer versions of CMake you can set compiler and linker flags for a single target with target_compile_options and target_link_libraries respectively (yes, the latter sets linker options too):

target_compile_options(first-test PRIVATE -fexceptions)

The advantage of this method is that you can control propagation of options to other targets that depend on this one via PUBLIC and PRIVATE.

As of CMake 3.13 you can also use target_link_options to add linker options which makes the intent more clear.

Solution 3

Try setting the variable CMAKE_CXX_FLAGS instead of CMAKE_C_FLAGS:

set (CMAKE_CXX_FLAGS "-fexceptions")

The variable CMAKE_C_FLAGS only affects the C compiler, but you are compiling C++ code.

Adding the flag to CMAKE_EXE_LINKER_FLAGS is redundant.

Solution 4

The preferred way to specify toolchain-specific options is using CMake's toolchain facility. This ensures that there is a clean division between:

• instructions on how to organise source files into targets -- expressed in CMakeLists.txt files, entirely toolchain-agnostic; and
• details of how certain toolchains should be configured -- separated into CMake script files, extensible by future users of your project, scalable.

Ideally, there should be no compiler/linker flags in your CMakeLists.txt files -- even within if/endif blocks. And your program should build for the native platform with the default toolchain (e.g. GCC on GNU/Linux or MSVC on Windows) without any additional flags.

Steps to add a toolchain:

1. Create a file, e.g. arm-linux-androideadi-gcc.cmake with global toolchain settings:

   set(CMAKE_CXX_COMPILER arm-linux-gnueabihf-g++)
   set(CMAKE_CXX_FLAGS_INIT "-fexceptions")
   

   (You can find an example Linux cross-compiling toolchain file here.)

2. When you want to generate a build system with this toolchain, specify the CMAKE_TOOLCHAIN_FILE parameter on the command line:

   mkdir android-arm-build && cd android-arm-build
   cmake -DCMAKE_TOOLCHAIN_FILE=$(pwd)/../arm-linux-androideadi-gcc.cmake ..
   

   (Note: you cannot use a relative path.)

3. Build as normal:

   cmake --build .
   

Toolchain files make cross-compilation easier, but they have other uses:

• Hardened diagnostics for your unit tests.

  set(CMAKE_CXX_FLAGS_INIT "-Werror -Wall -Wextra -Wpedantic")
  

• Tricky-to-configure development tools.

  # toolchain file for use with gcov
  set(CMAKE_CXX_FLAGS_INIT "--coverage -fno-exceptions -g")
  

• Enhanced safety checks.

  # toolchain file for use with gdb
  set(CMAKE_CXX_FLAGS_DEBUG_INIT "-fsanitize=address,undefined -fsanitize-undefined-trap-on-error")
  set(CMAKE_EXE_LINKER_FLAGS_INIT "-fsanitize=address,undefined -static-libasan")
  

Solution 5

You can also add linker flags to a specific target using the LINK_FLAGS property:

set_property(TARGET ${target} APPEND_STRING PROPERTY LINK_FLAGS " ${flag}")

If you want to propagate this change to other targets, you can create a dummy target to link to.

View more solutions

Comments

[Offirmo]

right now I'm having the same problem, and I'm trying different things. Hang a little and I post an answer. For compile flags, there is an unclean but easy way : add_definitions("-truc")

[ComicSansMS]

For a more up-to-date discussion on this question (especially if you are using CMake 3.x or newer): What is the modern method for setting general compile flags in CMake?.

[Gabriel Devillers]

If the link flags you want aim at configuring rpath then have a look at the specific CMake rpath commands gitlab.kitware.com/cmake/community/wikis/doc/cmake/…

[solti]

i tried that but it still gives error. Is set(CMAKE_CXX_FLAGS "-fexceptions") the only way to specify compiler flag.

[solti]

i solved the problem but not in a good way its a poor workaround .. i made -DCMAKE_CXX_FLAGS= "-fexceptions" in the command line. for some reason cmake is not reading flags from the .cmake file. :( .. thank you sakra for your answer ..

[evandrix]

-DCMAKE_CXX_FLAGS= "-fexceptions" There should NOT be a space between the = and "

[leinaD_natipaC]

why is add_definitions() unclean?

[Benoit Blanchon]

@leinaD_natipaC: The official documentation says: This command can be used to add any flags, but it is intended to add preprocessor definitions. I think that's why.

[zaizen]

Regarding what you said: "for some reason cmake is not reading flags from the .cmake file." Make sure you clear up the existing cache. This can be done by deleting everything from the build directory before cmake again.

[Paweł Szczur]

I've tried to use it: target_compile_options(main_static PRIVATE --static) but it doesn't seem to work, any idea why?

[vitaut]

-static is probably a linker, not compiler option. Try passing it to target_link_libraries.

[Paweł Szczur]

Oh, target_link_libraries I've missed that part of doc: "Specify libraries or flags to use when linking a given target.". Thanks.

[ComicSansMS]

A recent addition: CMake 3.13 introduces target_link_options as a cleaner way to specify linker flags. You should avoid using target_link_libraries for linker flags in the future and use target_link_options instead.

[Bruce Adams]

There is also add_compile_options - see stackoverflow.com/questions/39501481/… and more recently add_link_options

[m4l490n]

how do you specify multiple linker options?

[vitaut]

@m4l490n you pass multiple arguments to target_link_options.

[val is still with Monica]

@BruceAdams But please, never use them in modern target-based CMake.

[Bruce Adams]

@val I agree, but qualified with an almost. There are some valid uses for global project settings where cmake doens't have them yet. So not for enabling C++11 but maybe for enabling certain sanitisers when debugging.

[Harald Scheirich]

While this is the accepted answer this really show very old style CMAKE, refer to the answer by @vitaut for how any new CMAKE code should be structured with regard to compile time parameters

[bloody]

string(APPEND CMAKE_EXE_LINKER_FLAGS "new_value") is shorter and cleaner than set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} new_value")

[Alex Reinking]

While this is better than the accepted answer, it is still missing a generator expression to prevent that flag from being added to an incompatible compiler. But since this flag is only meant to be used in a specific compiler, it should be added to a tool chain file in the variable CMAKE_CXX_FLAGS_INIT

[John McFarlane]

@AlexReinking I wrote an answer involving toolchains. I wasn't aware of the _INIT variants however. Thanks

[Alex Reinking]

Don't set CMAKE_<LANG>_FLAGS in a toolchain. And there's no such thing as CMAKE_CXX_DEBUG_FLAGS. It's CMAKE_CXX_FLAGS_DEBUG. And you shouldn't use that either. Only set CMAKE_<LANG>_FLAGS[_<CONFIG>]_INIT in a toolchain

[Alex Reinking]

See docs for CMAKE_<LANG>_FLAGS_<CONFIG>_INIT and CMAKE_<LANG>_FLAGS_INIT

[Alex Reinking]

In general, in CMake, the variables CMAKE_<LANG>_FLAGS[_<CONFIG>] are meant to be set by the client building your app/library. They should never be programatically set. Appended to, rarely.

[John McFarlane]

@AlexReinking updated, plus CMAKE_EXE_LINKER_FLAGS_INIT.

[CodeMonkey]

This was the answer, after much searching thank you @JohnMcFarlane !

[apmccartney]

outdated advice

[wheredidthatnamecomefrom]

That's what add_definitions is for.

[John McFarlane]

@AlexReinking passing -DCMAKE_<LANG>_FLAGS to cmake appears to override CMAKE_<LANG>_FLAGS_INIT. For this reason, I'm tempted to use a custom flag and set it explicitly in CMakeLists.txt.