Post JSON data to RESTful datasnap server from delphi client
21,831
Here's some simple XE2 test code sending JSON data through HTTP Post using SuperObject (using Indy's TIdHTTP
):
procedure TFrmTTWebserviceTester.Button1Click(Sender: TObject);
var
lJSO : ISuperObject;
lRequest: TStringStream;
lResponse: String;
begin
// Next 2 lines for Fiddler HTTP intercept:
IdHTTP.ProxyParams.ProxyServer := '127.0.0.1';
IdHTTP.ProxyParams.ProxyPort := 8888;
lJSO := SO('{"name": "Henri Gourvest", "vip": true, "telephones": ["000000000", "111111111111"], "age": 33, "size": 1.83, "adresses": [ { "adress": "blabla", "city": "Metz", "pc": 57000 }, { "adress": "blabla", "city": "Nantes", "pc": 44000 } ]}');
lRequest := TStringStream.Create(lJSO.AsString, TEncoding.UTF8);
try
IdHTTP.Request.ContentType := 'application/json';
IdHTTP.Request.Charset := 'utf-8';
try
lResponse := IdHTTP.Post('http://127.0.0.1:8085/ttposttest', lRequest);
ShowMessage(lResponse);
except
on E: Exception do
ShowMessage('Error on request:'#13#10 + E.Message);
end;
finally
lRequest.Free;
end;
lJSO := nil;
end;
This is the data that goes out:
POST http://127.0.0.1:8085/ttposttest HTTP/1.0
Content-Type: application/json; charset=utf-8
Content-Length: 204
Connection: keep-alive
Host: 127.0.0.1:8085
Accept: text/html, */*
Accept-Encoding: identity
User-Agent: Mozilla/3.0 (compatible; Indy Library)
{"vip":true,"age":33,"telephones":["000000000","111111111111"],"adresses":[{"adress":"blabla","pc":57000,"city":"Metz"},{"adress":"blabla","pc":44000,"city":"Nantes"}],"size":1.83,"name":"Henri Gourvest"}
Receiver is a TWebAction
on a TWebModule
, with handler:
procedure TWebModuleWebServices.WebModuleWebServicesTTPostTestAction(
Sender: TObject; Request: TWebRequest; Response: TWebResponse;
var Handled: Boolean);
var
S : String;
lJSO: ISuperObject;
begin
S := Request.Content;
if S <> '' then
lJSO := SO('{"result": "OK", "encodingtestcharacters": "Typed € with Alt-0128 Will be escaped to \u20ac"}')
else
lJSO := SO('{"result": "Error", "message": "No data received"}');
Response.ContentType := 'application/json'; // Designating the encoding is somewhat redundant for JSON (http://stackoverflow.com/questions/9254891/what-does-content-type-application-json-charset-utf-8-really-mean)
Response.Charset := 'utf-8';
Response.Content := lJSO.AsJSON;
Handled := true;
end; { WebModuleWebServicesTTPostTestAction }
It uses TIdHTTPWebBrokerBridge
:
FWebBrokerBridge := TIdHTTPWebBrokerBridge.Create(Self);
// Register web module class.
FWebBrokerBridge.RegisterWebModuleClass(TWebModuleWebServices);
// Settings:
FWebBrokerBridge.DefaultPort := 8085;
This is the actual response:
HTTP/1.1 200 OK
Connection: close
Content-Type: application/json; charset=utf-8
Content-Length: 92
{"encodingtestcharacters":"Typed\u20acwithAlt0128FollowedBy8364escaped\u8364","result":"OK"}
Author by
Prince Agrawal
Updated on September 29, 2020Comments
-
Prince Agrawal over 3 years
I need to send a simple JSON object to a Restful datasnap server (Delphi) from a Delphi client. I am using Delphi XE. Can anybody help me out with the code? I am trying for hours but not getting it.. Please ask if details are not sufficient
Edit: Here is server side method declaration:
procedure updatemethodnme(str:string):string;
and here is client side code:
function PostData(request: string): boolean; var param: TStringList; url, Text,str: string; code: Integer; http: TIDHttp; begin Result:= false; http:= TIDHttp.Create(nil); http.HandleRedirects:= true; http.ReadTimeout:= 50000; http.request.Connection:= 'keep-alive'; str:= '{"lamp":"'+lamp+'","floor":"'+floor+'","op":"'+request+'"}'; param:= TStringList.Create; param.Clear; param.Add(str); url:= 'h***p://xx2.168.xx.xx:xxxx/Datasnap/rest/TserverMethods1/methdname/'; try Text:= http.Post(url, param); Result:= true; except on E: Exception do begin Result := false; end; end; end;
-
Jerry Dodge almost 11 yearsI was going to mention exactly this, except that I'm unsure if the OP needs help with the Client, Server, or Both.
-
Remy Lebeau almost 11 yearsI thought it was very clear in his first sentence: "I need to send a simple JSON object to a Restful datasnap server (Delphi) from a Delphi client".
-
Jerry Dodge almost 11 yearsI understand that's the server-side which is being used, and there's also a client-side as well, both written in Delphi. I'm just not sure if the difficulties are related to the Client, Server, or Both.
-
Remy Lebeau almost 11 yearsAre you joking? It's clear that he is trying to write a client that needs to post to a server.
-
Prince Agrawal almost 11 yearsI've tried with indy idhttp component already.. actually m not getting hw to encode json data in client side. earlier I sent a string & an integer by idhttp n it worked... but no idea how to deal with json
-
Jerry Dodge almost 11 years@achievelimitless The the issue is with serializing JSON data?
-
Remy Lebeau almost 11 years@achievelimitless: put the JSON data into a
TStringStream
orTMemoryStream
and thenPost()
that. You will likely need to set theTIdHTTP.Request.ContentType
to'application/json'
, and maybe theTIdHTTP.Request.Charset
as well. -
Remy Lebeau almost 11 years@achievelimitless: you are posting the JSON data using a
TStringList
, which is wrong. You have to use aTStream
instead, like I mentioned earlier. Posting aTStringList
creates a very different kind of HTTP request body than posting aTStream
. -
Prince Agrawal almost 11 yearsHey.. thanx for the reply... Client side m able to send data using super object. but coming to server side, I want to use datasnap servermethods only. is there any way to do that?
-
saeed khalafinejad over 3 yearsWhat do you mean by using ISuperObject? When you are using lJSO.AsString then that super object is useless.