xsl remove all non-numeric characters and leading 1

Question

I need to convert incoming phone number strings to a standardized format that does not have any non-numeric characters and strips off the leading number if it is 1.

For example:

"[phone] x 5555" becomes "22233344445555"

Thanks in advance for your help!

Solution 1

I. XSLT 1.0 solution:

This transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:template match="text()">
  <xsl:variable name="vnumsOnly" select=
  "translate(., translate(.,'0123456789',''), '')
  "/>

  <xsl:value-of select=
  "substring($vnumsOnly, (substring($vnumsOnly,1,1)='1') +1)"/>
 </xsl:template>
</xsl:stylesheet>

when applied on this XML document:

<t>"[phone] x 5555</t>

produces the wanted, correct result:

22233344445555

Explanation:

1. The expression: translate(.,'0123456789','') is evaluated to a string that contains all non-numeric characters in the current node.

2. We use 1. above in the expression:

   translate(., translate(.,'0123456789',''), '')

and this evaluates to a string where all non-numeric characters from the current node are deleted.

.3. The expression: (substring($vnumsOnly,1,1)='1') +1)" evaluates to 2 if the first character of $vnumsOnly is '1' and it evaluates to 1 if the starting character isn't '1'.

.4. We use 3. in the following expression:

substring($vnumsOnly, (substring($vnumsOnly,1,1)='1') +1)

which evaluates to the same string $vnumsOnly if it doesn't start with '1' and it evaluates to its substring starting from the 2nd character, if the first character is '1'.

---

II. XPath 2.0 solution:

Just use:

replace(replace(., '[^0-9]', ''), '^1', '')

The inner replace removes all characters that aren't 0 through 9 (digits). The outer replace removes the leading 1 (if it exists).

Solution 2

replace(replace(., '[^1-9]', ''), '^1', '') - I am responding to this... Instead of [^1-9]... Use [^0-9] otherwise any 0's in the phone number get deleted. But other than that this fixed my Workday integration issue great!

Comments

[MattM]

Thanks! This works perfectly. I really appreciate the explanation too.

[Nateous]

@DimitreNovatchev does this also work for the translate above? translate($phone,'0123456789'+$phone,'0123456789') instead of translate(., translate(.,'0123456789',''), '') which is better?

[Dimitre Novatchev]

@Nate, The expression you propose probably will produce the correct result. However, it can require extensive memory -- especially when the input string is significantly long. The "double-translate" method doesn't construct a second string that is longer than the input string.