CMD nested double quotes in argument
Solution 1
Like dbenham said, it's seems impossible to escape a space in a parameter without quotes.
But it could be possible if you know how the receiver function gets the parameters.
Then you could tranfer the parameter via an escaped delayed variable, the variable will be expanded not in the call, it will be expanded just in the function.
And it's necessary that the parameters will be assigned in the function to variables, but this could be the case in a good and readable code.
setlocal EnableDelayedExpansion
set path_with_space="c:\test\filenamewith space.txt"
@CALL :FUNCTION blaat1, "blaat2 ^!path_with_space^!"
GOTO :EOF
:FUNCTION
@echo off
echo arg 1: %~1
echo arg 2: %~2
echo arg 3: %~3
GOTO :EOF
The output is:
arg 1: blaat1
arg 2: blaat2 "c:\test\filenamewith space.txt"
arg 3:
EDIT: Soltution with batch injection
This works even when delayed expansion should be always disabled.
But then you need to now how the parameters are expanded in the function.
@echo off
set path_with_space="c:\test\filenamewith space.txt"
CALL :FUNCTION 1 2 ""^^"&call:inject:""
exit/b
:inject
set arg1=blaat1
set arg2=blaat2 %path_with_space%
set arg3=none
exit /b
:FUNCTION
@echo off
set "arg1=%~1"
set "arg2=%~2"
set "arg3=%~3"
echo arg 1: %arg1%
echo arg 2: %arg2%
echo arg 3: %arg3%
GOTO :EOF
Solution 2
I found this but all i could do was move the issue around to different areas.
@SET
path_with_space="c:\test\filenamewith space.txt"
:: Remove quotes
@SET _string=###%path_with_space%###
@SET _string=%_string:"###=%
@SET _string=%_string:###"=%
@SET _string=%_string:###=%
@echo %_string%
@CALL :FUNCTION blaat1, "blaat2 %_string%"
@GOTO :EOF
:FUNCTION
@echo off
@echo arg 1: %~1
@echo arg 2: %~2
@echo arg 3: %~3
:EOF
pause
Solution 3
I don't believe it is possible.
It is not possible to escape a space such that it is not interpreted as a parameter delimiter. The only way to include a space in a parameter is to enclose it in quotes. You require some space to be quoted and some not, so it is impossible.
Solution 4
@jeb +1
@davor
why don't use simply double-double quotes
@SET path_with_space=""c:\test\filenamewith space.txt""
@CALL :FUNCTION blaat1, "blaat2 %path_with_space%", blaat3
@GOTO :EOF
:FUNCTION
@echo off
echo arg 1: %~1
::--------------------
set arg2=%~2
set arg2=%arg2:""="%
::-------------------
echo arg 2: %arg2%
echo arg 3: %~3
GOTO :EOF
The output is:
arg 1: blaat1
arg 2: blaat2 "c:\test\filenamewith space.txt"
arg 3: blaat3
Related videos on Youtube
Davor Josipovic
Updated on July 07, 2022Comments
-
Davor Josipovic about 2 years
I am having problems with passing arguments to a batch function with nested double quotes.
Here is an example of a batch file:
@SET path_with_space="c:\test\filenamewith space.txt" @CALL :FUNCTION blaat1, "blaat2 %path_with_space%" @GOTO :EOF :FUNCTION @echo off echo arg 1: %~1 echo arg 2: %~2 echo arg 3: %~3 GOTO :EOF
The output is:
arg 1: blaat1 arg 2: blaat2 "c:\test\filenamewith arg 3: space.txt""
What should I do to make
arg 2: blaat2 "c:\test\filenamewith space.txt"
? Note that I cannot adjust the function or change the%path_with_space%
. I can only control what is passed to the function. -
Davor Josipovic almost 12 yearsThe output is:
arg 1: blaat1 arg 2: blaat2 c:\test\filenamewith space.txt arg 3:
Nice try, but the quotes are gone :( -
Davor Josipovic almost 12 yearsIt seems so. I also tried escaping the
%
, but without success. -
jeb almost 12 yearsThis would work too, but ... The precondition of the OP was Note that I cannot adjust the function
-
dbenham almost 12 yearsmy turn - WOW. It took me a while to figure out how your batch injection works. The last quote isn't needed, but it does make the quotes balanced. Very interesting how the colon ends the label in the CALL, and everything after is effectively a comment up until any token delimiter. That is new for me.
-
Davor Josipovic over 7 yearsThis would work too, but ... The precondition of the OP was Note that I cannot adjust the function
-
NetwOrchestration over 7 years@DavorJosipovic Yeah, I leave it for someone who can, I also update my answer to mention it needs editing funtion.