Interacting with the UI thread from an Async callback method?

Question

I have a method that is asynchronously called when System.Net.Sockets.NetworkStream.BeginRead completes.

 skDelegate = New AsyncCallback(AddressOf skDataReceived)
 skStream.BeginRead(skBuffer, 0, 100000, skDelegate, New Object)

In that callback method, I need to interact with the UI thread.

Sub skDataReceived(ByVal result As IAsyncResult)
    CType(My.Application.OpenForms.Item("frmMain"), frmMain).refreshStats(d1, d2)
End Sub

This causes an exception after the method completes. (when End Sub is executed)

The Undo operation encountered a context that is different from what was applied in the corresponding Set operation. The possible cause is that a context was Set on the thread and not reverted(undone).

So how do I interact with the UI thread from the callback method? What am I doing wrong?

Solution 1

You have to use Invoke or BeginInvoke on the frmMain object to enqueue a message (a delegate) to execute on the UI thread.

Here's how I'd do it in C#.

frmMain.Invoke(() => frmMain.refreshStats(d1, d2));

Also check this list of Invoke types and their uses.

Solution 2

Travis is correct. Windows forms application are single threaded, you can not access the UI from any other thread. You need to marshall the call to UI thread using BeginInvoke.

See : http://msdn.microsoft.com/en-us/library/0b1bf3y3.aspx

Solution 3

You need to have the UI Thread invoke the frmMain.refreshStats method. There is of-course many ways of doing this using the Control.InvokeRequired property, and Control.Invoke (MSDN Documentation).

You can either have the "EndAsync" method make the method call UI thread safe, or have the refreshStats method check for thread safety (using Control.InvokeRequired).

EndAsync UI thread-safe would be something like this:

Public Delegate Sub Method(Of T1, T2)(ByVal arg1 As T1, ByVal arg2 As T2)

Sub skDataReceived(ByVal result As IAsyncResult)
    Dim frmMain As Form = CType(My.Application.OpenForms.Item("frmMain"), frmMain)
    Dim d As Method(Of Object, Object)
'create a generic delegate pointing to the refreshStats method
    d = New Method(Of Object, Object)(AddressOf frmMain.refreshStats)
'invoke the delegate under the UI thread
    frmMain.Invoke(d, New Object() {d1, d2})
End Sub

Or you can have the refreshStats method check to see if it needs to invoke itself under the UI thread:

Public Delegate Sub Method(Of T1, T2)(ByVal arg1 As T1, ByVal arg2 As T2)

Sub refreshStats(ByVal d1 As Object, ByVal d2 As Object)
'check to see if current thread is the UI thread
    If (Me.InvokeRequired = True) Then
        Dim d As Method(Of Object, Object)
'create a delegate pointing to itself
        d = New Method(Of Object, Object)(AddressOf Me.refreshStats)
'then invoke itself under the UI thread
        Me.Invoke(d, New Object() {d1, d2})
    Else
        'actual code that requires UI thread safety goes here
    End If
End Sub